<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package AutoLoader;

use 5.005_64;
our(@EXPORT, @EXPORT_OK, $VERSION);

my $is_dosish;
my $is_epoc;
my $is_vms;
my $is_macos;

BEGIN {
    require Exporter;
    @EXPORT = @EXPORT = ();
    @EXPORT_OK = @EXPORT_OK = qw(AUTOLOAD);
    $is_dosish = $^O eq 'dos' || $^O eq 'os2' || $^O eq 'MSWin32';
    $is_epoc = $^O eq 'epoc';
    $is_vms = $^O eq 'VMS';
    $is_macos = $^O eq 'MacOS';
    $VERSION = '5.58';
}

AUTOLOAD {
    my $sub = $AUTOLOAD;
    my $filename;
    # Braces used to preserve $1 et al.
    {
	# Try to find the autoloaded file from the package-qualified
	# name of the sub. e.g., if the sub needed is
	# Getopt::Long::GetOptions(), then $INC{Getopt/Long.pm} is
	# something like '/usr/lib/perl5/Getopt/Long.pm', and the
	# autoload file is '/usr/lib/perl5/auto/Getopt/Long/GetOptions.al'.
	#
	# However, if @INC is a relative path, this might not work.  If,
	# for example, @INC = ('lib'), then $INC{Getopt/Long.pm} is
	# 'lib/Getopt/Long.pm', and we want to require
	# 'auto/Getopt/Long/GetOptions.al' (without the leading 'lib').
	# In this case, we simple prepend the 'auto/' and let the
	# C&lt;require&gt; take care of the searching for us.

	my ($pkg,$func) = ($sub =~ /(.*)::([^:]+)$/);
	$pkg =~ s#::#/#g;
	if (defined($filename = $INC{"$pkg.pm"})) {
	    if ($is_macos) {
		$pkg =~ tr#/#:#;
		$filename =~ s#^(.*)$pkg\.pm\z#$1auto:$pkg:$func.al#s;
	    } else {
		$filename =~ s#^(.*)$pkg\.pm\z#$1auto/$pkg/$func.al#s;
	    }

	    # if the file exists, then make sure that it is a
	    # a fully anchored path (i.e either '/usr/lib/auto/foo/bar.al',
	    # or './lib/auto/foo/bar.al'.  This avoids C&lt;require&gt; searching
	    # (and failing) to find the 'lib/auto/foo/bar.al' because it
	    # looked for 'lib/lib/auto/foo/bar.al', given @INC = ('lib').

	    if (-r $filename) {
		unless ($filename =~ m|^/|s) {
		    if ($is_dosish) {
			unless ($filename =~ m{^([a-z]:)?[\\/]}is) {
			     $filename = "./$filename";
			}
		    }
		    elsif ($is_epoc) {
			unless ($filename =~ m{^([a-z?]:)?[\\/]}is) {
			     $filename = "./$filename";
			}
		    }elsif ($is_vms) {
			# XXX todo by VMSmiths
			$filename = "./$filename";
		    }
		    elsif (!$is_macos) {
			$filename = "./$filename";
		    }
		}
	    }
	    else {
		$filename = undef;
	    }
	}
	unless (defined $filename) {
	    # let C&lt;require&gt; do the searching
	    $filename = "auto/$sub.al";
	    $filename =~ s#::#/#g;
	}
    }
    my $save = $@;
    eval { local $SIG{__DIE__}; require $filename };
    if ($@) {
	if (substr($sub,-9) eq '::DESTROY') {
	    *$sub = sub {};
	} else {
	    # The load might just have failed because the filename was too
	    # long for some old SVR3 systems which treat long names as errors.
	    # If we can succesfully truncate a long name then it's worth a go.
	    # There is a slight risk that we could pick up the wrong file here
	    # but autosplit should have warned about that when splitting.
	    if ($filename =~ s/(\w{12,})\.al$/substr($1,0,11).".al"/e){
		eval { local $SIG{__DIE__}; require $filename };
	    }
	    if ($@){
		$@ =~ s/ at .*\n//;
		my $error = $@;
		require Carp;
		Carp::croak($error);
	    }
	}
    }
    $@ = $save;
    goto &amp;$sub;
}

sub import {
    my $pkg = shift;
    my $callpkg = caller;

    #
    # Export symbols, but not by accident of inheritance.
    #

    if ($pkg eq 'AutoLoader') {
      local $Exporter::ExportLevel = 1;
      Exporter::import $pkg, @_;
    }

    #
    # Try to find the autosplit index file.  Eg., if the call package
    # is POSIX, then $INC{POSIX.pm} is something like
    # '/usr/local/lib/perl5/POSIX.pm', and the autosplit index file is in
    # '/usr/local/lib/perl5/auto/POSIX/autosplit.ix', so we require that.
    #
    # However, if @INC is a relative path, this might not work.  If,
    # for example, @INC = ('lib'), then
    # $INC{POSIX.pm} is 'lib/POSIX.pm', and we want to require
    # 'auto/POSIX/autosplit.ix' (without the leading 'lib').
    #

    (my $calldir = $callpkg) =~ s#::#/#g;
    my $path = $INC{$calldir . '.pm'};
    if (defined($path)) {
	# Try absolute path name.
	$path =~ s#^(.*)$calldir\.pm$#$1auto/$calldir/autosplit.ix#;
	eval { require $path; };
	# If that failed, try relative path with normal @INC searching.
	if ($@) {
	    $path ="auto/$calldir/autosplit.ix";
	    eval { require $path; };
	}
	if ($@) {
	    my $error = $@;
	    require Carp;
	    Carp::carp($error);
	}
    } 
}

sub unimport {
  my $callpkg = caller;
  eval "package $callpkg; sub AUTOLOAD;";
}

1;

__END__

=head1 NAME

AutoLoader - load subroutines only on demand

=head1 SYNOPSIS

    package Foo;
    use AutoLoader 'AUTOLOAD';   # import the default AUTOLOAD subroutine

    package Bar;
    use AutoLoader;              # don't import AUTOLOAD, define our own
    sub AUTOLOAD {
        ...
        $AutoLoader::AUTOLOAD = "...";
        goto &amp;AutoLoader::AUTOLOAD;
    }

=head1 DESCRIPTION

The B&lt;AutoLoader&gt; module works with the B&lt;AutoSplit&gt; module and the
C&lt;__END__&gt; token to defer the loading of some subroutines until they are
used rather than loading them all at once.

To use B&lt;AutoLoader&gt;, the author of a module has to place the
definitions of subroutines to be autoloaded after an C&lt;__END__&gt; token.
(See L&lt;perldata&gt;.)  The B&lt;AutoSplit&gt; module can then be run manually to
extract the definitions into individual files F&lt;auto/funcname.al&gt;.

B&lt;AutoLoader&gt; implements an AUTOLOAD subroutine.  When an undefined
subroutine in is called in a client module of B&lt;AutoLoader&gt;,
B&lt;AutoLoader&gt;'s AUTOLOAD subroutine attempts to locate the subroutine in a
file with a name related to the location of the file from which the
client module was read.  As an example, if F&lt;POSIX.pm&gt; is located in
F&lt;/usr/local/lib/perl5/POSIX.pm&gt;, B&lt;AutoLoader&gt; will look for perl
subroutines B&lt;POSIX&gt; in F&lt;/usr/local/lib/perl5/auto/POSIX/*.al&gt;, where
the C&lt;.al&gt; file has the same name as the subroutine, sans package.  If
such a file exists, AUTOLOAD will read and evaluate it,
thus (presumably) defining the needed subroutine.  AUTOLOAD will then
C&lt;goto&gt; the newly defined subroutine.

Once this process completes for a given function, it is defined, so
future calls to the subroutine will bypass the AUTOLOAD mechanism.

=head2 Subroutine Stubs

In order for object method lookup and/or prototype checking to operate
correctly even when methods have not yet been defined it is necessary to
"forward declare" each subroutine (as in C&lt;sub NAME;&gt;).  See
L&lt;perlsub/"SYNOPSIS"&gt;.  Such forward declaration creates "subroutine
stubs", which are place holders with no code.

The AutoSplit and B&lt;AutoLoader&gt; modules automate the creation of forward
declarations.  The AutoSplit module creates an 'index' file containing
forward declarations of all the AutoSplit subroutines.  When the
AutoLoader module is 'use'd it loads these declarations into its callers
package.

Because of this mechanism it is important that B&lt;AutoLoader&gt; is always
C&lt;use&gt;d and not C&lt;require&gt;d.

=head2 Using B&lt;AutoLoader&gt;'s AUTOLOAD Subroutine

In order to use B&lt;AutoLoader&gt;'s AUTOLOAD subroutine you I&lt;must&gt;
explicitly import it:

    use AutoLoader 'AUTOLOAD';

=head2 Overriding B&lt;AutoLoader&gt;'s AUTOLOAD Subroutine

Some modules, mainly extensions, provide their own AUTOLOAD subroutines.
They typically need to check for some special cases (such as constants)
and then fallback to B&lt;AutoLoader&gt;'s AUTOLOAD for the rest.

Such modules should I&lt;not&gt; import B&lt;AutoLoader&gt;'s AUTOLOAD subroutine.
Instead, they should define their own AUTOLOAD subroutines along these
lines:

    use AutoLoader;
    use Carp;

    sub AUTOLOAD {
        my $sub = $AUTOLOAD;
        (my $constname = $sub) =~ s/.*:://;
        my $val = constant($constname, @_ ? $_[0] : 0);
        if ($! != 0) {
            if ($! =~ /Invalid/ || $!{EINVAL}) {
                $AutoLoader::AUTOLOAD = $sub;
                goto &amp;AutoLoader::AUTOLOAD;
            }
            else {
                croak "Your vendor has not defined constant $constname";
            }
        }
        *$sub = sub { $val }; # same as: eval "sub $sub { $val }";
        goto &amp;$sub;
    }

If any module's own AUTOLOAD subroutine has no need to fallback to the
AutoLoader's AUTOLOAD subroutine (because it doesn't have any AutoSplit
subroutines), then that module should not use B&lt;AutoLoader&gt; at all.

=head2 Package Lexicals

Package lexicals declared with C&lt;my&gt; in the main block of a package
using B&lt;AutoLoader&gt; will not be visible to auto-loaded subroutines, due to
the fact that the given scope ends at the C&lt;__END__&gt; marker.  A module
using such variables as package globals will not work properly under the
B&lt;AutoLoader&gt;.

The C&lt;vars&gt; pragma (see L&lt;perlmod/"vars"&gt;) may be used in such
situations as an alternative to explicitly qualifying all globals with
the package namespace.  Variables pre-declared with this pragma will be
visible to any autoloaded routines (but will not be invisible outside
the package, unfortunately).

=head2 Not Using AutoLoader

You can stop using AutoLoader by simply

	no AutoLoader;

=head2 B&lt;AutoLoader&gt; vs. B&lt;SelfLoader&gt;

The B&lt;AutoLoader&gt; is similar in purpose to B&lt;SelfLoader&gt;: both delay the
loading of subroutines.

B&lt;SelfLoader&gt; uses the C&lt;__DATA__&gt; marker rather than C&lt;__END__&gt;.
While this avoids the use of a hierarchy of disk files and the
associated open/close for each routine loaded, B&lt;SelfLoader&gt; suffers a
startup speed disadvantage in the one-time parsing of the lines after
C&lt;__DATA__&gt;, after which routines are cached.  B&lt;SelfLoader&gt; can also
handle multiple packages in a file.

B&lt;AutoLoader&gt; only reads code as it is requested, and in many cases
should be faster, but requires a mechanism like B&lt;AutoSplit&gt; be used to
create the individual files.  L&lt;ExtUtils::MakeMaker&gt; will invoke
B&lt;AutoSplit&gt; automatically if B&lt;AutoLoader&gt; is used in a module source
file.

=head1 CAVEATS

AutoLoaders prior to Perl 5.002 had a slightly different interface.  Any
old modules which use B&lt;AutoLoader&gt; should be changed to the new calling
style.  Typically this just means changing a require to a use, adding
the explicit C&lt;'AUTOLOAD'&gt; import if needed, and removing B&lt;AutoLoader&gt;
from C&lt;@ISA&gt;.

On systems with restrictions on file name length, the file corresponding
to a subroutine may have a shorter name that the routine itself.  This
can lead to conflicting file names.  The I&lt;AutoSplit&gt; package warns of
these potential conflicts when used to split a module.

AutoLoader may fail to find the autosplit files (or even find the wrong
ones) in cases where C&lt;@INC&gt; contains relative paths, B&lt;and&gt; the program
does C&lt;chdir&gt;.

=head1 SEE ALSO

L&lt;SelfLoader&gt; - an autoloader that doesn't use external files.

=cut
</pre></body></html>